I seem to recall that it is not actually possible to ask a cell  whether it
has a name. There are a couple of ways to work around this.

1) Assign the name of the cell to a string, but: (a) prefill the string
with a special value or an empty string, and (b) put the assignment
statement under On Error Resume Next. E.g.

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Address <> "$A$1" Then
Dim XX As String
XX = "No"
On Error Resume Next
XX = Target.Name.Name
On Error GoTo 0
Range("A1").Value = XX
End If
End Sub

puts into A1 the name of the cell if it has one, or "No".

2) Use Intersect. E.g.

Private Sub Worksheet_Change(ByVal Target As Range)
If Not Intersect(Target, Range("aa")) Is Nothing Then
Range("A1").Value = "aa"
ElseIf Not Intersect(Target, Range("bb")) Is Nothing Then
Range("A1").Value = "bb"
ElseIf Target.Address <> "$A$1" Then
Range("A1").Value = "Nothing"
End If
End Sub

does specific  checks for names "aa" and "bb".

If you are using .address to compare, then try something like this:

if target.address = [myData].address then 'bingo!

While the functional use of VBA's Error-Trap is interesting, I have
many other tests in my Change() Sub. Errors in any of the other
sections of the procedure would have to be handled with the same
"do-nothing" routine; which may not be appropriate.
While it works, the "Not Intersect is Nothing" "double negative"
test seemes awkward. I selected Tou's because the address  technique
seems more intuitive. Actually, looking at it, it appears to be "the
correct way". I tried, but just couldn't get the correct  object
heirarchy/accessors.

However, I did test  both techniques and show the actual tests here
for completeness should anyone else benefit.
Regards, Steve, Noskowicz.
P.S.
Because the code  also does corrections on cell  values, I turn off
events first in the Change() Sub [Application.EnableEvents = False]
and back on at the end [Application.EnableEvents = True].

' The original "fixed-cell" [direct address reference] code.

If Target.Address = "$X$3" Then
' Handle the change  in cell X3
ElseIf Target.Address = "$X$4" Then
' Handle the change in cell X4
End If

The following techniques, using Cell Range-Names, allow relocating the
cells on the sheet without re-writing the code. Both techniques do
not error  if a non-Named cell is changed.

Note that initially, cell X3 is RangeNamed Mem_First and X4 is
RangeNamed Mem_Last


"Address" technique:
If Target.Address = Sheet3.Range("Mem_First").Address Then
' Handle the change in cell X3
ElseIf Target.Address = Sheet3.Range("Mem_Last").Address Then
' Handle the change in cell X4
End If

"Intersect" technique:
If Not Intersect(Target, Range("Mem_First")) Is Nothing Then
' Handle the change in cell X3
ElseIf Not Intersect(Target, Range("Mem_Last")) Is Nothing Then
' Handle the change in cell X4
End If

No, not necessary. What you do is put

On Error Resume Next

immediately before the statement in question and then

On Error GoTo 0

immediately after it.

From my example:

> XX = "No"
> On Error Resume Next
> XX = Target.Name.Name
> On Error GoTo 0

Better, though, is to encapsulate the bit of code  involved into a
function (or subroutine). This is a little function from my common
functions that returns the name of a range  if it has one.

Public Function CellRangeName(ByVal TheCell As Range) As String
CellRangeName = ""
On Error Resume Next
CellRangeName = TheCell.Name.Name
End Function

In this case, the On Error will be cancelled when the function finishes.

I agree with the awkward look of the double  negative, but there is no "is
something" unfortunately.

I also like Tou's comparison of addresses. It certainly has a "clean" feel
to it.

I do this all the time... But I use a variable to catch the error number  so
I can immediately reset error  trapping. Otherwise we get into resetting
error trapping all over the place.

On Error Resume Next
... Line of code  that could error
lgErrNum = Err.Number
On Error GoTo 0
Select case lgErrNum
Case ....
Case ....
Case Else
End select

I figured I needed to do more reading about VBA's On Error. The
positioning of those statements in your code  and the Goto 0 alerted me
that something more was to be learned. I briefly pondered asking, but
I had my immediate solution.